COMMENT ⊗   VALID 00005 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002
C00006 00003	cmchar "The letter C"
C00010 00004	cmchar "The letter D"
C00013 00005
C00016 ENDMK
C⊗;
cmchar "The letter C";
if serifs: beginchar("C",13u#,cap_height#,0);
 italcorr cap_height#*slant-.5u#;
 adjust_fit(0,0);
 numeric curliness; curliness=.5;
 pickup fine_pen; penpos1(cap_hair-fine,0); penpos2(vair+hair_corr-fine,90);
 penpos3(cap_curve-fine,180); penpos4(vair+hair_corr-fine,270);
 penpos5(hair-fine,360);
 rt x1r=rt x5r=round(w-u); lft x3r=round u; x2=x4=.55[x3,x1];
 top y2r=h+o; bot y4r=-o; y3=.5[y2,y4];
 bot y1=round max(.6h,x_height-.5fine); y5=good.y .95(h-y1);
 (x2l,y2l')=whatever[z2r,z1l]; y2l:=y2l';
 (x4l,y4l')=whatever[z4r,z5l]; y4l:=y4l';
 filldraw stroke z1e{curl curliness}
  ..z2e{left}&pulled_super_arc.e(2,3,superpull)
  & pulled_super_arc.e(3,4,superpull)&z4e{right}..z5e; % arc
 x6=x1r; top y6=h; lft x7=x1l-cap_curve; y7=y1;
 path upper_arc; upper_arc=z1{curl curliness}..z2{left};
 numeric t; t=xpart(upper_arc intersectiontimes (z6..z7));
 filldraw subpath(0,t) of upper_arc--z6--z1r--z1--cycle; % barb
else: beginchar("C",11.5u#,cap_height#,0);
 italcorr cap_height#*slant-.5u#;
 adjust_fit(0,0);
 pickup fine_pen; penpos1(1.05flare-fine,90); penpos2(slab-fine,90);
 penpos3(cap_curve-fine,180); penpos4(slab-fine,270);
 penpos5(flare-fine,270);
 rt x1r=round(w-1.25u); x2=x4=.5w+1.25u;
 lft x3r=round max(u,2u-.5cap_curve); rt x5l=round(w-u);
 top y1r=round .95h+o; top y2r=h+o; y3=.5h; bot y4r=-o; bot y5r=round .07h-o;
 (x5l',y5l)=whatever[z5l,(w,h)]; x5l:=good.x x5l';
 filldraw stroke z1e..z2e{left}&super_arc.e(2,3)
  & super_arc.e(3,4) & z4e{right}..z5e; % arc and terminals
fi; math_fit(-.3cap_height#*slant-.5u#,halfic#);
penlabels(1,2,3,4,5,6,7); endchar;
cmchar "The letter D";
beginchar("D",13.5u#,cap_height#,0);
italcorr .7cap_height#*slant-.5u#;
adjust_fit(cap_serif_fit#,0);
numeric left_stem; left_stem=cap_stem-round stem_corr;
penpos1(left_stem-tiny,0); penpos2(left_stem-tiny,0);
pickup tiny_pen; top y1=h; bot y2=0;
lft x1l=lft x2l=round max(2u,3u-.5left_stem);
filldraw stroke z1e--z2e; % stem
penpos3(cap_band,90); penpos4(cap_band,90);
penpos5(cap_curve-stem_corr,0);
penpos6(cap_band,-90); penpos7(cap_band,-90);
z3r=top z1; y4=y3; y5=.51[y4,y6]; y6=y7;
z7r=bot z2; x4=x6=.5w+.25u; x5r=round(w-u);
x4l:=x6l:=x4-.25cap_curve;
fill stroke z3e..pulled_super_arc.e(4,5,superpull)
  & pulled_super_arc.e(5,6,superpull)..z7e;	% lobe
if serifs: cup_serif(1,2,a,b,1/3,-cap_jut,1/3,.5cap_jut);	% upper serif
 cup_serif(2,1,c,d,1/3,-cap_jut,1/3,.5cap_jut); fi	% lower serif
math_fit(0,.7cap_height#-u#); penlabels(1,2,3,4,5,6,7); endchar;